'VBA標準モジュール
Option Explicit

Sub findTest(txt As String)
    Dim prs As Presentation  'プレゼンテーション
    Dim sld As Slide    'スライド
    Dim shp As Shape    'シェイプ
    Dim txtRng As TextRange  'テキストレンジ
    Dim foundtext As TextRange  '文字発見用テキストレンジ
    Dim flgFind As Boolean    '文字発見フラグ
    Dim sldNum As Integer    '文字発見字のスライドNo
    Dim msg As String    'メッセージ内容
    Dim btm As Integer    'ボタン種類
    Dim ttl As String    'タイトル
    Dim response As Integer    'ボタン押した後の反応
    
    msg = "見つけたよ！！"
    btm = 4
    ttl = "メッセージ"
    flgFind = False

    For Each prs In Presentations  '全プレゼンテーションをループ
        For Each sld In prs.Slides  '全スライドをループ
            For Each shp In sld.Shapes  '全図形をループ
                If shp.HasTextFrame Then    'テキストフレーム有り
                    Set txtRng = shp.TextFrame.TextRange
                    Set foundtext = txtRng.Find(txt, msoFalse, msoFalse)
                    
                    '文字を発見した時
                    If Not (foundtext Is Nothing) Then
                        flgFind = True    '文字発見
                        With foundtext
                            sldNum = sld.SlideIndex  '検索ワードが記載されたスライドNo代入
                            prs.Windows(1).Activate  '検索ワードがあるプレゼンテーションをアクティブ化
                            ActiveWindow.View.GotoSlide Index:=sldNum    '検索ワードがあるスライドを開く
                            response = MsgBox(msg, btm, ttl)  'メッセージの返答に対する返り値
                            
                            'ボタンを押した後の反応
                            If response = vbYes Then    'YESの場合
                                shp.Select  '検索ワードを含むシェイプを選択
                                Exit Sub    'FindTestから抜ける
                            End If
                        End With
                    End If
                End If
            Next
        Next
    Next
    
    If flgFind = False Then
        MsgBox ("ごめんなさい、見つけられませんでした・・・")
    Else
        MsgBox ("検索終了")
    End If
End Sub